Fungsi SUM, SUMIF, dan SUMIFS

SUM (Fungsi SUM)

Artikel ini mendeskripsikan sintaks rumus dan penggunaan fungsiSUM di Microsoft Excel.

Deskripsi

Fungsi SUM menambah semua angka yang Anda tentukan sebagai argumen. Setiap argumen bisa merupakan rentang, referensi sel, array, konstanta, rumus, atau hasil dari fungsi lain. Sebagai contoh, SUM(A1:A5) menambah semua angka yang ada di sel A1 sampai A5. Contoh lainnya,, SUM(A1, A3, A5) menambah angka yang ada di sel A1, A3, dan A5.

Sintaks

SUM(number1,[number2],...)
Sintaks fungsi SUM memiliki argumen berikut:

• number1    Diperlukan. Argumen angka pertama yang ingin Anda tambahkan.
  
• number2, ...    Opsional. Argumen angka 2 sampai 255 yang ingin Anda tambahkan.
  

Keterangan

• Jika argumen adalah array atau referensi, hanya angka di dalam array atau referensi itu yang dihitung. Sel kosong, nilai logika, atau teks dalam array atau referensi diabaikan.
  
• Jika argumen adalah nilai kesalahan, atau jika argumen adalah teks yang tidak dapat diterjemahkan menjadi angka, Excel akan menampilkan kesalahan.
  

Contoh

Buku kerja di bawah ini memperlihatkan contoh fungsi ini. Periksalah contohnya, ubah rumus yang ada, atau masukkan rumus Anda sendiri untuk mempelajari cara kerja fungsi ini.
Salin contoh data di dalam tabel berikut ini dan tempel ke dalam sel A1 lembar kerja Excel yang baru. Agar rumus memperlihatkan hasil, pilih datanya, tekan F2, lalu tekan Enter. Jika perlu, Anda bisa menyesuaikan lebar kolom untuk melihat semua data.

Data
-5
15
30
'5
TRUE
Rumus	Deskripsi	Hasil
=SUM(3, 2)	Menambahkan 3 dan 2.	5
=SUM("5", 15, TRUE)	Menambahkan 5, 15 dan 1. Nilai teks "5" pertama-tama diterjemahkan menjadi angka, dan nilai logiks TRUE pertama-tama diterjemahkan menjadi angka 1.	21
=SUM(A2:A4)	Menambahkan nilai di sel A2 hingga A4.	40
=SUM(A2:A4, 15)	Menambahkan nilai di sel A2 hingga A4, lalu menambahkan 15 ke hasil tersebut.	55
=SUM(A5,A6, 2)	Menambahkan nilai di sel A5 dan A6, lalu menambahkan 2 ke hasil tersebut. Karena nilai non-numerik di dalam referensi tidak diterjemahkan — nilai di sel A5 ('5) dan nilai di sel A6 (TRUE) keduanya diperlakukan sebagai teks — nilai di sel tersebut diabaikan.	2

SUMIF (Fungsi SUMIF)

Artikel ini menguraikan sintaks rumus dan penggunaan fungsiSUMIF di Microsoft Excel.

Deskripsi

Anda bisa menggunakan fungsi SUMIF untuk menjumlahkan nilai dalam satu rentang yang memenuhi kriteria yang Anda tentukan. Sebagai contoh, di dalam kolom yang berisi angka, Anda hanya ingin menjumlahkan nilai-nilai yang lebih besar dari 5. Anda bisa menggunakan rumus berikut:
=SUMIF(B2:B25,">5")
Dalam contoh ini, kriteria itu akan diterapkan pada setiap nilai yang sama yang dijumlahkan. Jika Anda inginkan, Anda bisa menerapkan kriteria ke satu rentang dan menjumlahkan nilai yang terkait di rentang berbeda. Sebagai contoh, rumus =SUMIF(B2:B5, "John", C2:C5) hanya menjumlahkan nilai di rentang C2:C5, di mana sel yang terkait di rentang B2:B5 sama dengan "John."
Catatan   Untuk menjumlahkan sel berdasarkan beberapa kriteria, lihat fungsi SUMIFS.

Sintaks

SUMIF(rentang, kriteria, [sum_range])
Sintaks fungsi SUMIF memiliki argumen berikut:

• rentang    Diperlukan. Rentang sel yang ingin Anda evaluasi menurut kriteria. Sel di setiap rentang harus merupakan angka atau nama, array, atau referensi yang berisi angka. Sel kosong atau nilai teks diabaikan.
  
• kriteria    Diperlukan. Kriteria dalam bentuk angka, ekspresi, referensi sel, teks, atau fungsi yang menentukan sel apa yang akan ditambahkan. Sebagai contoh, kriteria dapat diekspresikan sebagai 32, ">32", B5, 32, "32", "apples", atau TODAY().
  Penting   Kriteria teks atau kriteria apa pun yang mencakup simbol logika atau matematika harus disertakan dalam tanda kutip ganda ("). Jika kriteria adalah numerik, tanda kutip ganda tidak diperlukan.
  
• sum_range    Opsional. Sel aktual untuk ditambahkan, jika Anda ingin menambahkan sel yang lain dari yang sudah ditentukan di argumen rentang. Jika argumen sum_range dihilangkan, Excel menambahkan sel yang ditentukan di argumen range (sel yang sama di mana kriteria diterapkan).
  

Catatan  

• Anda bisa menggunakan karakter wildcard — tanda tanya (?) dan tanda bintang (*) — sebagai argumen kriteria. Tanda tanya cocok dengan karakter tunggal apa pun; tanda bintang cocok dengan urutan karakter apa pun. Jika Anda ingin menemukan tanda tanya atau tanda bintang, ketikkan tilde (~) sebelum karakter.
  

Keterangan

• Fungsi SUMIF mengembalikan hasil yang tidak benar bila Anda menggunakannya untuk mencocokkan string yang lebih panjang dari 255 karakter ke string #VALUE!.
  
• Argumen sum_range tidak harus mempunyai ukuran dan bentuk yang sama dengan argumen range. Sel aktual yang ditambahkan ditentukan dengan menggunakan sel di paling kiri atas di dalam argumen sum_range sebagai sel awal, lalu menyertakan sel yang ukuran dan bentuknya sesuai dengan argumen range. Misalnya:
  

Jika rentangnya adalah	Dan sum_range adalah	Maka sel aktual adalah
A1:A5	B1:B5	B1:B5
A1:A5	B1:B3	B1:B5
A1:B4	C1:D4	C1:D4
A1:B4	C1:C2	C1:D4

Namun, bila argumen range dan sum_range di fungsi SUMIF tidak berisi jumlah sel yang sama, perhitungan ulang lembar kerja mungkin memakan waktu lebih lama dari yang diharapkan.

Contoh

Contoh 1

Buku kerja di bawah ini memperlihatkan contoh fungsi ini. Periksalah contohnya, ubah rumus yang ada, atau masukkan rumus Anda sendiri untuk mempelajari cara kerja fungsi ini.
Salin contoh data di dalam tabel berikut ini dan tempel ke dalam sel A1 lembar kerja Excel yang baru. Agar rumus memperlihatkan hasil, pilih datanya, tekan F2, lalu tekan Enter. Jika perlu, Anda bisa menyesuaikan lebar kolom untuk melihat semua data.

Nilai Properti	Komisi	Data
$ 100.000,00	$ 7.000,00	$ 250.000,00
$ 200.000,00	$ 14.000,00
$ 300.000,00	$ 21.000,00
$ 400.000,00	$ 28.000,00
Rumus	Deskripsi	Hasil
=SUMIF(A2:A5,">160000",B2:B5)	Jumlah komisi untuk nilai properti di atas 160.000.	$ 63.000,00
=SUMIF(A2:A5,">160000")	Jumlah nilai properti di atas 160.000.	$ 900.000,00
=SUMIF(A2:A5,300000,B2:B5)	Jumlah komisi untuk nilai properti yang sama dengan 300.000.	$ 21.000,00
=SUMIF(A2:A5,">" & C2,B2:B5)	Jumlah komisi untuk nilai properti lebih besar dari nilai di C2.	$ 49.000,00

Untuk bekerja secara lebih mendalam dengan data contoh di Excel, unduh buku kerja yang disematkan ke komputer Anda, lalu buka di Excel.

Contoh 2

Buku kerja di bawah ini memperlihatkan contoh fungsi ini. Periksalah contohnya, ubah rumus yang ada, atau masukkan rumus Anda sendiri untuk mempelajari cara kerja fungsi ini.
Salin contoh data di dalam tabel berikut ini dan tempel ke dalam sel A1 lembar kerja Excel yang baru. Agar rumus memperlihatkan hasil, pilih datanya, tekan F2, lalu tekan Enter. Jika perlu, Anda bisa menyesuaikan lebar kolom untuk melihat semua data.

Kategori	Makanan	Penjualan
Sayuran	Tomatoes	$ 2.300,00
Sayuran	Celery	$ 5.500,00
Buah	Oranges	$ 800,00
	Butter	$ 400,00
Sayuran	Carrots	$ 4.200,00
Buah	Apples	$ 1.200,00
Rumus	Deskripsi	Hasil
=SUMIF(A2:A7,"Buah",C2:C7)	Jumlah penjualan semua makanan dalam kategori "Buah".	$ 2.000,00
=SUMIF(A2:A7,"Sayuran",C2:C7)	Jumlah penjualan semua makanan dalam kategori "Sayuran".	$ 12.000,00
=SUMIF(B2:B7,"*es",C2:C7)	Jumlah penjualan semua makanan yang berakhiran "es" (Tomatoes, Oranges, dan Apples).	$ 4.300,00
=SUMIF(A2:A7,"",C2:C7)	Jumlah penjualan semua makanan yang tidak memiliki kategori khusus.	$ 400,00

SUMIFS (Fungsi SUMIFS)

Artikel ini menguraikan sintaks rumus dan penggunaan fungsiSUMIFS dalam Microsoft Excel.

Deskripsi

Menambahkan sel dalam rentang yang memenuhi beberapa kriteria. Misalnya, jika Anda ingin menambahkan angka dalam rentang A1:A20 hanya jika angka yang terkait dalam B1:B20 lebih besar dari nol (0) dan angka yang terkait dalam C1:C20 kurang dari 10, Anda bisa menggunakan rumus berikut:
=SUMIFS(A1:A20, B1:B20, ">0", C1:C20, "<10")
Penting   Susunan argumen berbeda antara fungsi SUMIFS dan SUMIF. Secara khusus, argumen sum_range adalah argumen pertama dalam SUMIFS, tapi merupakan argumen ketiga dalam SUMIF. Jika Anda menyalin dan mengedit fungsi serupa tersebut, pastikan Anda meletakkan argumen dalam urutan yang benar.

Sintaks

SUMIFS( sum_range , criteria_range1, criteria1, [criteria_range2, criteria2], ...)
Sintaks fungsi SUMIFS memiliki argumen berikut:

• Sum_range    Diperlukan. Satu atau beberapa sel yang akan ditambahkan, termasuk angka atau nama, rentang, atau referensi sel yang berisi angka. Sel kosong atau nilai teks diabaikan.
  
• Criteria_range1    Diperlukan. Rentang pertama untuk mengevaluasi kriteria yang terkait.
  
• Criteria1    Diperlukan. Kriteria dalam bentuk angka, ekspresi, referensi sel, atau teks yang menentukan sel mana saja dalam argumen Criteria_range1 yang akan ditambahkan. Misalnya, kriteria dapat diekspresikan sebagai 32, ">32", B4, "apples", atau "32."
  
• Criteria_range2, criteria2, …    Opsional. Rentang tambahan dan kriteria yang terkait. Hingga 127 pasangan rentang/kriteria yang diperbolehkan.
  

Keterangan

• Tiap sel dalam argumen Sum_range dijumlahkan hanya jika semua kriteria yang terkait yang ditentukan benar untuk sel itu. Misalnya, anggaplah bahwa sebuah rumus berisi dua argumen Criteria_range. Jika sel pertama dari Criteria_range1 memenuhi Criteria1, dan sel pertama dari Criteria_range2 memenuhi Critera2, sel pertama dari Sum_range ditambahkan ke penjumlahan tersebut, dan seterusnya, untuk sel lainnya dalam rentang yang ditentukan.
  
• Sel dalam argumen Sum_range yang berisi TRUE mengevaluasi ke 1; sel dalam Sum_range yang berisi FALSE mengevaluasi ke 0 (nol).
  
• Tidak seperti argumen rentang dan kriteria dalam fungsi SUMIF, dalam fungsi SUMIFS, tiap argumen Criteria_range harus berisi jumlah baris dan kolom yang sama dengan argumen Sum_range.
  
• Anda dapat menggunakan karakter wildcard — tanda tanya (?) dan tanda bintang (*) — dalam kriteria. Tanda tanya cocok dengan karakter tunggal apa pun; tanda bintang cocok dengan urutan karakter apa pun. Jika Anda ingin menemukan tanda tanya atau tanda bintang, ketikkan tilde (~) sebelum karakter.
  

Contoh

Buku kerja di bawah ini memperlihatkan contoh fungsi ini. Periksalah contohnya, ubah rumus yang ada, atau masukkan rumus Anda sendiri untuk mempelajari cara kerja fungsi ini.
Salin contoh data di dalam tabel berikut ini dan tempel ke dalam sel A1 lembar kerja Excel yang baru. Agar rumus memperlihatkan hasil, pilih datanya, tekan F2, lalu tekan Enter. Jika perlu, Anda bisa menyesuaikan lebar kolom untuk melihat semua data.